Création d'interactivité avec ActionScript > Création d'interactivité complexe > Création de commandes audio

 

Création de commandes audio

L'objet intégré Sound permet de contrôler les sons d'une animation. Pour utiliser les méthodes de l'objet Sound, vous devez tout d'abord en créer un nouveau. Vous pouvez ensuite utiliser la méthode attachSound pour insérer un son de la bibliothèque dans une animation pendant sa lecture.

Vous pouvez afficher une démonstration animée de contrôles audio en cliquant sur le bouton de lecture et en réglant le volume et la balance.

La méthode setVolume de l'objet Sound contrôle le volume et la méthode setPan règle la balance gauche et droite d'un son.

Les procédures suivantes expliquent comment créer des contrôles audio semblables à ceux qui sont présentés ci-dessus.

Pour associer un son à un scénario :

1

Choisissez Fichier > Importer pour importer un son.

2

Sélectionnez le son dans la bibliothèque, cliquez du bouton droit et choisissez Options > Liaison.

3

Activez les options Exporter pour ActionScript et Exporter dans la première image, puis affectez-lui l'identifiant a_thousand_ways.

4

Ajoutez un bouton sur la scène et appelez-le playButtton.

5

Ajoutez un bouton sur la scène et appelez-le stopButton.

6

Ajoutez un clip sur la scène et appelez-le speaker.

7

Sélectionnez l'image 1 dans le scénario principal, puis choisissez Fenêtre > Actions.

8

Pour mettre l'animation en pause jusqu'à ce que l'utilisateur clique sur le bouton de lecture, dans la boîte à outils Actions, cliquez sur la catégorie Objets, puis sur Animation, puis sur Sound, puis sur Méthodes et double-cliquez sur stop. Entrez _root.speaker dans le champ Objet.

9

Pour créer un objet Sound, dans la boîte à outils Actions, cliquez sur la catégorie Objets, puis sur Animation, puis sur Sound et double-cliquez sur new Sound. Entrez song = dans le champ Expression.

10

Dans la boîte à outils Actions, cliquez sur la catégorie Objets, puis sur Animation, puis sur Sound, puis sur Méthodes et double-cliquez sur attachSound. Entrez chanson dans le champ Objet et "a_thousand_ways" (y compris les guillemets) dans le champ Paramètres.

11

Pour démarrer la lecture, dans la boîte à outils Actions, cliquez sur la catégorie Objets, puis sur Animation, puis sur Sound, puis sur Méthodes et double-cliquez sur start.

12

Pour activer le haut-parleur, dans la boîte à outils Actions, cliquez sur la catégorie Objets, puis sur Animation, puis sur MovieClip, puis sur Méthodes et double-cliquez sur play. Entrez _root.speaker dans le champ Objet.

Le code devrait avoir cette forme :

 
_root.speaker.stop();
song = new Sound();
song.attachSound("a_thousand_ways");
_root.playButton.onRelease = function() {
    song.start();
    _root.speaker.play();
};

13

Pour arrêter le haut-parleur à la fin de la chanson, dans la boîte à outils Actions, cliquez sur la catégorie Objets, puis sur Animation, puis sur Sound, puis sur Méthodes et double-cliquez sur onSoundComplete. Entrez song dans le champ Objet. Entrez onSoundComplete dans le champ Méthode.

14

Dans la boîte à outils Actions, cliquez sur la catégorie Objets, puis sur Animation, puis sur Sound, puis sur Méthodes et double-cliquez sur stop. Entrez _root.speaker dans le champ Objet.

Le code devrait avoir cette forme :

 
_root.speaker.stop();
song = new Sound();
song.attachSound("a_thousand_ways");
_root.playButton.onRelease = function() {
    song.start();
    _root.speaker.play();
    song.onSoundComplete = function() {
        _root.speaker.stop();
    };
};

15

Choisissez Contrôle > Tester l'animation pour écouter le son.

Pour créer une commande de volume réglable :

1

Faites glisser un bouton sur la scène.

2

Sélectionnez le bouton et choisissez Insertion > Convertir en symbole. Faites attention à bien choisir le comportement de clip.

Cela crée un clip avec le bouton sur sa première image.

3

Sélectionnez le clip et choisissez Edition > Modifier le symbole.

4

Sélectionnez le bouton et choisissez Fenêtre > Actions.

5

Entrez les actions suivantes :

 
on (press) {
    startDrag("", false, left, top, right, bottom);
}
on (release) {
    stopDrag();
}

Les paramètres de startDrag, left, top, right et bottom, sont des variables définies dans une action de clip.

6

Choisissez Edition > Modifier le document pour revenir au scénario principal.

7

Sélectionnez le clip sur la scène.

8

Entrez les actions suivantes : 

onClipEvent(load) {
    top = _y;
    bottom = _y;
    left = _x;
    right = _x+100;
    _x += 100;
}
onClipEvent (enterFrame) {
    _root.song.setVolume(_x-left);
}

9

Choisissez Contrôle > Tester l'animation pour utiliser la commande de volume.

Pour créer une commande de balance réglable :

1

Faites glisser un bouton sur la scène.

2

Sélectionnez le bouton et choisissez Insertion > Convertir en symbole. Choisissez la propriété du clip.

3

Sélectionnez le clip et choisissez Edition > Modifier le symbole.

4

Sélectionnez le bouton et choisissez Fenêtre > Actions.

5

Entrez les actions suivantes :

 
on (press) {
	startDrag ("", false, left, top, right, bottom);
	dragging = true;
}
on (release, releaseOutside) {
	stopDrag ();
	dragging = false;
}

Les paramètres de startDrag, left, top, right et bottom, sont des variables définies dans une action de clip.

6

Choisissez Edition > Modifier le document pour revenir au scénario principal.

7

Sélectionnez le clip sur la scène.

8

Entrez les actions suivantes :

 
onClipEvent(load) {
	top=_y;
	bottom=_y;
	left=_x-50;
	right=_x+50;
	center=_x;
}

onClipEvent(enterFrame){
	if (dragging==true){
		_root.s.setPan((_x-center)*2);
	}
}

9

Choisissez Contrôle > Tester l'animation pour utiliser la commande de balance.

Pour plus d'informations sur les méthodes de l'objet Sound, consultez l'entrée Sound (objet) dans le dictionnaire ActionScript.